bar

#Names and values

bar(x: North, South, East; y: 42, 31, 55) stands a bar at each name, reaching from the baseline to its value. x and y are series, as a scatter's are: paired by position, written out or bound whole (bar(x: #sales.region; y: #sales.revenue)). Exactly one axis is ruled in names — by the names in its series under auto, or by x format: / y format: — and the other is the value axis, which always reaches the baseline. Which axis holds the names is the orientation: names on y lay the bars out sideways.

bar(x: 1, 2, 3; y: 42, 31, 55)

Bars on a numeric axis are a histogram, whose widths are bin edges. A list in colour is cycled bar by bar, so one bar is picked out by its place in the list — colour: grey, grey, grey, red, grey colours the fourth. A map colours bars by their data: colour: #sales.region -> (North: orange) picks out the bar standing at North, the rest keeping the default blue, and colour: #self.value -> (..<0: red; 0..: teal) the bars by their values (Styling marks from data). show-labels writes each value at its bar's end.

#Several bars at one name

Each bar written is one series. Where several have a bar at the same name they split the band there in source order; where only one does, its bar takes the band whole. band is the share of the band the bars at a name fill. stack stands a bar's values on top of the bar written before it, name by name, so a run of stacked bars builds one column. A hidden bar takes no share of the band.

Show code

graph{
    @data#sales{
        region | y2023 | y2024
        North  | 38.0  | 42.1
        South  | 33.5  | 31.4
        East   | 47.2  | 55.0
        West   | 26.1  | 27.8
    }

    bar(x: #sales.region; y: #sales.y2023; colour: grey; label: 2023)
    bar(x: #sales.region; y: #sales.y2024; colour: blue; label: 2024)
}(
    y axis label: revenue (£k)
)

#Bars over periods

Long-format data has one row per name per period. slice names the period column, and the bars show the period that the scene's parameter over that column holds — a slider or selector whose column: is the same column. A numeric period column glides between the periods either side; a column of names selects one. @data covers the shape of the rows.

graph{
    slider:t(column: #sales.year; name: Year)
    bar(x: #sales.region; y: #sales.revenue; slice: #sales.year)
}

#Error bars

error draws a capped bar through the middle of each bar's end, along the value axis, in the bar's edge colour. It is written as a scatter's is: a half-width per bar, such as a standard deviation, or the interval's two ends, error: #trials.lo .. #trials.hi.

Show code

graph{
    @data#yield{
        feed     | mean | sd
        Control  | 4.1  | 0.6
        Nitrogen | 5.6  | 0.8
        Compost  | 5.0  | 0.5
        Both     | 6.3  | 0.9
    }

    bar(x: #yield.feed; y: #yield.mean; error: #yield.sd; colour: teal)
}(
    y axis label: yield (t/ha)
)

A stack bar ends at a running total rather than at its own reading, so it takes no error; neither does a rose or a column in space (canvas/plane-attribute).

#Roses and columns

On the polar plane a bar chart is a rose: the bars stand at names on theta and reach out along r, so theta must be ruled in names (canvas/bar-axes). In space, bar(x: …; y: …; z: …) stands a column at each (x, y) on the floor, as tall as its z; either floor axis may be names or numbers, and stack and show-labels are refused.